From nookDevs

CM7 Standard

This is the standard CM7 'updater-script' for the NOOKcolor (encore). Consider this the 'right' way to do things (for the most part), although it takes significantly more work to generate than embedding a 'tar' archive inside the ZIP file.

assert(getprop("ro.product.device") == "encore" || getprop("ro.build.product") == "encore" || getprop("ro.product.board") == "encore");
package_extract_file("system/bin/backuptool.sh", "/tmp/backuptool.sh");
set_perm(0, 0, 0777, "/tmp/backuptool.sh");
run_program("/tmp/backuptool.sh", "backup");
show_progress(0.500000, 0);
format("ext4", "EMMC", "/dev/block/mmcblk0p5");
mount("ext4", "EMMC", "/dev/block/mmcblk0p5", "/system");
package_extract_dir("recovery", "/system");
package_extract_dir("system", "/system");
symlink("busybox", "/system/xbin/[", "/system/xbin/[[",
        "/system/xbin/arp", "/system/xbin/ash", "/system/xbin/awk",
        "/system/xbin/basename", "/system/xbin/bbconfig", "/system/xbin/brctl",
        "/system/xbin/bunzip2", "/system/xbin/bzcat", "/system/xbin/bzip2",
        "/system/xbin/cal", "/system/xbin/cat", "/system/xbin/catv",
        "/system/xbin/chgrp", "/system/xbin/chmod", "/system/xbin/chown",
        "/system/xbin/chroot", "/system/xbin/cksum", "/system/xbin/clear",
        "/system/xbin/cmp", "/system/xbin/cp", "/system/xbin/cpio",
        "/system/xbin/cut", "/system/xbin/date", "/system/xbin/dc",
        "/system/xbin/dd", "/system/xbin/depmod", "/system/xbin/devmem",
        "/system/xbin/df", "/system/xbin/diff", "/system/xbin/dirname",
        "/system/xbin/dmesg", "/system/xbin/dnsd", "/system/xbin/dos2unix",
        "/system/xbin/du", "/system/xbin/echo", "/system/xbin/ed",
        "/system/xbin/egrep", "/system/xbin/env", "/system/xbin/expr",
        "/system/xbin/false", "/system/xbin/fdisk", "/system/xbin/fgrep",
        "/system/xbin/find", "/system/xbin/fold", "/system/xbin/free",
        "/system/xbin/freeramdisk", "/system/xbin/fuser", "/system/xbin/getopt",
        "/system/xbin/grep", "/system/xbin/gunzip", "/system/xbin/gzip",
        "/system/xbin/head", "/system/xbin/hexdump", "/system/xbin/id",
        "/system/xbin/ifconfig", "/system/xbin/insmod", "/system/xbin/install",
        "/system/xbin/ip", "/system/xbin/kill", "/system/xbin/killall",
        "/system/xbin/killall5", "/system/xbin/length", "/system/xbin/less",
        "/system/xbin/ln", "/system/xbin/losetup", "/system/xbin/ls",
        "/system/xbin/lsmod", "/system/xbin/lspci", "/system/xbin/lsusb",
        "/system/xbin/lzop", "/system/xbin/lzopcat", "/system/xbin/md5sum",
        "/system/xbin/mkdir", "/system/xbin/mke2fs", "/system/xbin/mkfifo",
        "/system/xbin/mkfs.ext2", "/system/xbin/mknod", "/system/xbin/mkswap",
        "/system/xbin/mktemp", "/system/xbin/modprobe", "/system/xbin/more",
        "/system/xbin/mount", "/system/xbin/mountpoint", "/system/xbin/mv",
        "/system/xbin/netstat", "/system/xbin/nice", "/system/xbin/nohup",
        "/system/xbin/nslookup", "/system/xbin/ntpd", "/system/xbin/od",
        "/system/xbin/patch", "/system/xbin/pgrep", "/system/xbin/pidof",
        "/system/xbin/ping", "/system/xbin/pkill", "/system/xbin/printenv",
        "/system/xbin/printf", "/system/xbin/ps", "/system/xbin/pwd",
        "/system/xbin/rdev", "/system/xbin/readlink", "/system/xbin/realpath",
        "/system/xbin/renice", "/system/xbin/reset", "/system/xbin/rm",
        "/system/xbin/rmdir", "/system/xbin/rmmod", "/system/xbin/route",
        "/system/xbin/run-parts", "/system/xbin/sed", "/system/xbin/seq",
        "/system/xbin/setsid", "/system/xbin/sh", "/system/xbin/sha1sum",
        "/system/xbin/sha256sum", "/system/xbin/sha512sum",
        "/system/xbin/sleep", "/system/xbin/sort", "/system/xbin/split",
        "/system/xbin/stat", "/system/xbin/strings", "/system/xbin/stty",
        "/system/xbin/swapoff", "/system/xbin/swapon", "/system/xbin/sync",
        "/system/xbin/sysctl", "/system/xbin/tac", "/system/xbin/tail",
        "/system/xbin/tar", "/system/xbin/tee", "/system/xbin/telnet",
        "/system/xbin/test", "/system/xbin/tftp", "/system/xbin/time",
        "/system/xbin/top", "/system/xbin/touch", "/system/xbin/tr",
        "/system/xbin/traceroute", "/system/xbin/true", "/system/xbin/tty",
        "/system/xbin/tune2fs", "/system/xbin/umount", "/system/xbin/uname",
        "/system/xbin/uniq", "/system/xbin/unix2dos", "/system/xbin/unlzop",
        "/system/xbin/unzip", "/system/xbin/uptime", "/system/xbin/usleep",
        "/system/xbin/uudecode", "/system/xbin/uuencode", "/system/xbin/vi",
        "/system/xbin/watch", "/system/xbin/wc", "/system/xbin/wget",
        "/system/xbin/which", "/system/xbin/whoami", "/system/xbin/xargs",
        "/system/xbin/yes",
        "/system/xbin/zcat");
symlink("toolbox", "/system/bin/cat", "/system/bin/cmp",
        "/system/bin/date", "/system/bin/dd", "/system/bin/dmesg",
        "/system/bin/getevent", "/system/bin/getprop", "/system/bin/hd",
        "/system/bin/id", "/system/bin/ifconfig", "/system/bin/iftop",
        "/system/bin/insmod", "/system/bin/ioctl", "/system/bin/ionice",
        "/system/bin/kill", "/system/bin/log", "/system/bin/lsmod",
        "/system/bin/mkdir", "/system/bin/nandread", "/system/bin/netstat",
        "/system/bin/newfs_msdos", "/system/bin/notify", "/system/bin/printenv",
        "/system/bin/ps", "/system/bin/reboot", "/system/bin/renice",
        "/system/bin/rmdir", "/system/bin/rmmod", "/system/bin/route",
        "/system/bin/schedtop", "/system/bin/sendevent",
        "/system/bin/setconsole", "/system/bin/setprop", "/system/bin/sleep",
        "/system/bin/smd", "/system/bin/start", "/system/bin/stop",
        "/system/bin/sync", "/system/bin/top", "/system/bin/uptime",
        "/system/bin/vmstat", "/system/bin/watchprops",
        "/system/bin/wipe");
set_perm_recursive(0, 0, 0755, 0644, "/system");
set_perm_recursive(0, 2000, 0755, 0755, "/system/bin");
set_perm(0, 3003, 02750, "/system/bin/netcfg");
set_perm(0, 3004, 02755, "/system/bin/ping");
set_perm(0, 2000, 06750, "/system/bin/run-as");
set_perm(1002, 1002, 0440, "/system/etc/dbus.conf");
set_perm(1014, 2000, 0550, "/system/etc/dhcpcd/dhcpcd-run-hooks");
set_perm_recursive(0, 2000, 0755, 0750, "/system/etc/init.d");
set_perm(0, 0, 0755, "/system/etc/init.d");
set_perm(0, 2000, 0550, "/system/etc/init.goldfish.sh");
set_perm_recursive(0, 0, 0755, 0555, "/system/etc/ppp");
set_perm_recursive(0, 2000, 0755, 0755, "/system/xbin");
set_perm(0, 0, 06755, "/system/xbin/librank");
set_perm(0, 0, 06755, "/system/xbin/procmem");
set_perm(0, 0, 06755, "/system/xbin/procrank");
set_perm(0, 0, 06755, "/system/xbin/su");
set_perm(0, 0, 06755, "/system/xbin/tcpdump");
show_progress(0.200000, 0);
show_progress(0.200000, 10);
package_extract_file("system/bin/backuptool.sh", "/tmp/backuptool.sh");
set_perm(0, 0, 0777, "/tmp/backuptool.sh");
run_program("/tmp/backuptool.sh", "restore");
package_extract_file("system/bin/verify_cache_partition_size.sh", "/tmp/verify_cache_partition_size.sh");
set_perm(0, 0, 0777, "/tmp/verify_cache_partition_size.sh");
run_program("/tmp/verify_cache_partition_size.sh");
show_progress(0.200000, 10);
mount("vfat", "EMMC", "/dev/block/mmcblk0p1", "/boot");
package_extract_file("kernel", "/boot/uImage");
package_extract_file("ramdisk.img", "/boot/uRamdisk");
show_progress(0.100000, 0);
unmount("/boot");
unmount("/system");

Generic Sample

Here is a sample Edify 'updater-script' laying out example commands for several common (and not-so-common) operations. This framework shows how to use 'format' and 'tar' instead of 'dd' to install a new ROM, which are almost as easy to create as using 'dd' but should produce smaller distribution files.

##
## updater-script template for flashing to eMMC on NOOKcolor
##
ui_print("");
ui_print("Flashing custom image to eMMC");


## Unpack tools
set_progress(0);
ui_print("");
ui_print("Extracting tools");
show_progress(0.1, 1);
assert(package_extract_dir("tools", "/tmp"));
## Copy busybox and tune2fs from CWR ramdisk
## Copy mkdosfs from B&N factory.zip
set_perm(0, 0, 0755, "/tmp/busybox");
set_perm(0, 0, 0755, "/tmp/mkdosfs");
set_perm(0, 0, 0755, "/tmp/tune2fs");

## Create clean mountpoints
run_program("/tmp/busybox", "mkdir", "/NFmnt", "/NFmnt2", "/NFmnt3");
ui_print("Done");


## Rebuild boot partition
ui_print("");
ui_print("Rebuilding boot partition");
show_progress(0.2, 2);

## Reformat boot partition (usually not necessary)
ifelse(is_mounted("/dev/block/mmcblk0p1"),assert(unmount("/dev/block/mmcblk0p1") == 0),0);
assert(run_program("/tmp/mkdosfs", "-F 32", "/dev/block/mmcblk0p1") == 0);
assert(mount("vfat", "/dev/block/mmcblk0p1", "/NFmnt") == "/NFmnt");
assert(package_extract_file("boot/MLO", "/NFmnt/MLO"));
assert(package_extract_file("boot/u-boot.bin", "/NFmnt/u-boot.bin"));

## Copy kernel and ramdisk.  This may be enough in most cases
assert(package_extract_file("boot/uImage", "/NFmnt/uImage"));
assert(package_extract_file("boot/uRamdisk", "/NFmnt/uRamdisk"));

## Replace recovery kernel and ramdisk.
## XXXX Normally this is done separately from installing a new ROM
assert(package_extract_file("boot/uRecImg", "/NFmnt/uRecImg"));
assert(package_extract_file("boot/uRecRam", "/NFmnt/uRecRam"));
ui_print("Done");


## Install /system
ui_print("");
ui_print("Unpacking /system");
show_progress(0.4, 30);

## Copy archive file to /cache
assert(package_extract_file("system.tgz", "/cache/system.tgz"));

## Format partition
ifelse(is_mounted("/dev/block/mmcblk0p5"),assert(unmount("/dev/block/mmcblk0p5") == 0),0);
#assert(run_program("/tmp/busybox", "mke2fs", "/dev/block/mmcblk0p5") == 0);
assert(format("ext2", "/dev/block/mmcblk0p5"));

## Unpack archive
assert(mount("ext2", "/dev/block/mmcblk0p5", "/NFmnt2") == "/NFmnt2");
assert(run_program("/tmp/busybox", "tar", "xpzf", "/cache/system.tgz", "-C", "/NFmnt2") == 0);

## Clean up
delete("/cache/system.tgz");
ui_print("Done");


## Install /data
ui_print("");
ui_print("Unpacking /data");
show_progress(0.6, 30);

## Copy archive file to /cache
assert(package_extract_file("data.tgz", "/cache/data.tgz"));

## Format partition (not always necessary)
ifelse(is_mounted("/dev/block/mmcblk0p6"),assert(unmount("/dev/block/mmcblk0p6") == 0),0);
#assert(run_program("/tmp/busybox", "mke2fs", "-j", "/dev/block/mmcblk0p6") == 0);
assert(format("ext2", "/dev/block/mmcblk0p6"));
assert(run_program("/tmp/tune2fs", "-j", "/dev/block/mmcblk0p6"));

## Unpack archive
assert(mount("ext3", "/dev/block/mmcblk0p6", "/NFmnt3") == "/NFmnt3");
assert(run_program("/tmp/busybox", "tar", "xpzf", "/cache/data.tgz", "-C", "/NFmnt3") == 0);

## Clear dalvik cache (Always needed w/updated /system)
delete_recursive("/NFmnt3/dalvik-cache");

## Clear package settings
delete("/data/system/packages.xml");

## Clean up
delete("/cache/data.tgz");
ui_print("Done");


## Clear /cache
ui_print("");
show_progress(0.8, 5);

#ui_print("Formatting cache");
#ifelse(is_mounted("/cache"),assert(unmount("/cache") == 0),0);
#assert(run_program("/tmp/busybox", "mke2fs", "-j", "/dev/block/mmcblk0p7") == 0);
#assert(mount("ext2", "/dev/block/mmcblk0p7", "/cache") == "/cache");

ui_print("Clearing cache");
delete_recursive("/cache");


## Clean up
set_progress(1);
## XXXX Warning: unmount does not block
unmount("/NFmnt");
unmount("/NFmnt2");
unmount("/NFmnt3");
## Alternate way to unmount filesystems using busybox
#assert(run_program("/tmp/busybox", "umount", "/NFmnt"));
#assert(run_program("/tmp/busybox", "umount", "/NFmnt2"));
#assert(run_program("/tmp/busybox", "umount", "/NFmnt3"));
delete("/NFmnt", "/NFmnt2", "/NFmnt3");
delete("/tmp/busybox", "/tmp/mkdosfs", "/tmp/tune2fs");
ui_print("Finished!");
ui_print("");
ui_print("Remove the sdcard and reboot");